宝塔线_分析家公式网

请问飞狐软件的宝塔线是如何写出来的？编写公式是怎么的？

 

解答如下：

INPUT:n(5,1,999),k(1,0,1);//n为均线参数；k=0取消画图标和均线

fc:=c;fo:=o;hh:=0*c;ll:=0*c;rr:=0*c;tj:=0*c;

tj[1]:=if(fc[1]>=fo[1],1,0);

hh[1]:=max(fc[1],fo[1]);

ll[1]:=min(fc[1],fo[1]);

rr[1]:=fo[1];

for i=2 to datacount do begin

if tj[i-1]=1 then begin

if fc[i]>=rr[i-1] then begin

tj[i]:=1;

hh[i]:=max(fc[i],hh[i-1]);

ll[i]:=min(fc[i],hh[i-1]);

rr[i]:=ll[i];

end; else begin

tj[i]:=0;

hh[i]:=hh[i-1];

ll[i]:=fc[i];

rr[i]:=rr[i-1];

end;

end; else begin

if fc[i]<=rr[i-1] then begin

tj[i]:=0;

hh[i]:=max(fc[i],ll[i-1]);

ll[i]:=min(fc[i],ll[i-1]);

rr[i]:=hh[i];

end; else begin

tj[i]:=1;

hh[i]:=fc[i];

ll[i]:=ll[i-1];

rr[i]:=rr[i-1];

end;

end;

end;

STICKLINE(tj=1,hh,ll,7,1),COLORRED;

STICKLINE(tj=0,hh,ll,7,0),COLORCYAN;

STICKLINE(ref(tj=0,1) and tj=1,rr,ll,7,0),COLORCYAN;

STICKLINE(ref(tj=1,1) and tj=0,rr,hh,7,1),COLORRED;

三平底翻红:tj=1 and ref(tj=0,1) and ref(tj=0,2) and ll=ref(ll,1) and ll=ref(ll,2),LINETHICK,COLORRED;

三平顶翻绿:tj=0 and ref(tj=1,1) and ref(tj=1,2) and hh=ref(hh,1) and hh=ref(hh,2),LINETHICK,COLORGREEN;

if k=0 then exit;

DRAWICON(三平底翻红,ll*0.98,4);DRAWICON(三平顶翻绿,hh*1.02,5);

均线:ma(c,n),COLORMAGENTA;PARTLINE(均线<=ref(均线,1),均线),COLORGREEN;